SET NOCOUNT ON

IF (SUBSTRING(CAST(SERVERPROPERTY ('ProductVersion') AS varchar(50)),1,CHARINDEX('.',CAST(SERVERPROPERTY ('ProductVersion') AS varchar(50)))-1) >= 11)

BEGIN

    DECLARE @UTCDateDiff int = DATEDIFF(mi,GETUTCDATE(),GETDATE());

    SELECT TOP 1 CAST(xet.target_data AS XML) AS XMLDATA INTO #SystemHealthSessionData

    FROM sys.dm_xe_session_targets xet

        JOIN sys.dm_xe_sessions xe ON (xe.address = xet.event_session_address)

    WHERE xe.name = 'system_health' AND xet.target_name = 'ring_buffer';

    WITH CTE_HealthSession (EventXML) AS

    (

    SELECT C.query('.') EventXML

    FROM #SystemHealthSessionData a

        CROSS APPLY a.XMLDATA.nodes('/RingBufferTarget/event') as T(C)

    )

    SELECT

        DATEADD(mi,@UTCDateDiff,EventXML.value('(/event/@timestamp)[1]', 'datetime')) as EventTime,

        EventXML.value('(/event/data/value)[3]', 'int') as process_utilization,

        EventXML.value('(/event/data/value)[4]', 'int') as system_idle,

        EventXML.value('(/event/data/value)[7]', 'float') as page_faults,

        EventXML.value('(/event/data/value)[8]', 'float') as working_set_delta,

        EventXML.value('(/event/data/value)[9]', 'int') as memory_utilization

    FROM CTE_HealthSession

    WHERE EventXML.value('(/event/@name)[1]', 'varchar(255)') = 'scheduler_monitor_system_health_ring_buffer_recorded'

    ORDER BY EventTime;

    DROP TABLE #SystemHealthSessionData;

END

SET NOCOUNT OFF